
**Quarter-over-quarter-to-date growth**

Quarter-over-quarter-to-date growth compares the quarter-to-date at a specific date with the quarter-to-date at an equivalent month in the previous quarter. Figure 8 shows that Sales PQTD in 2009 is taking into account transactions only until May 2009, which is the second month in the quarter. For this reason, Sales QTD of Q2-2009 is 2,618,644.64, whereas Sales PQTD for Q3-2009 is less: 1,746,058.45.



Sales PQTD filters the previous value in Year Quarter Number, and through Month In Quarter Number filters all the months in the quarter less than or equal to the last relative month of the quarter visible in the filter context:

Sales PQTD :=

VAR LastMonthInQuarterAvailable = MAX ( 'Date'[Month In Quarter Number] )

VAR LastYearQuarterAvailable = MAX ( 'Date'[Year Quarter Number] )

VAR PreviousYearQuarterAvailable = LastYearQuarterAvailable - 1

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Month In Quarter Number] <= LastMonthInQuarterAvailable,

        'Date'[Year Quarter Number] = PreviousYearQuarterAvailable

    )

RETURN

    Result

Sales QOQTD and Sales QOQTD % rely on Sales PQTD to guarantee a fair comparison:

Sales QOQTD :=

VAR ValueCurrentPeriod = [Sales QTD]

VAR ValuePreviousPeriod = [Sales PQTD]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod ) && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales QOQTD % :=


DIVIDE (

    [Sales QOQTD],

    [Sales PQTD]

)

Quarter-over-quarter-to-date growth compares the quarter-to-date at a specific date with the quarter-to-date at an equivalent date in the previous quarter.



Sales PQTD uses [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) and filters the Date[DateWithSales] column to guarantee a fair comparison of the last period with data. Sales QOQTD and Sales QOQTD % rely on Sales PQTD to guarantee the same fair comparison:

Sales PQTD :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales QTD],

        CALCULATETABLE (

            DATEADD ( 'Date'[Date], -1, QUARTER ),

            'Date'[DateWithSales] = TRUE

        )

    )

)

Sales QOQTD :=

VAR ValueCurrentPeriod = [Sales QTD]

VAR ValuePreviousPeriod = [Sales PQTD]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales QOQTD % :=

DIVIDE (

    [Sales QOQTD],

    [Sales PQTD]

)